Excel

Berechnung der Einkommensteuerklasse

Income Tax Bracket Calculation

Excel-Formel: Berechnung der EinkommensteuerklasseZusammenfassung

Um die Gesamteinkommensteuer basierend auf mehreren Steuerklassen zu berechnen, können Sie SVERWEIS und eine Tariftabelle verwenden, die wie im Beispiel gezeigt strukturiert ist. Die Formel in G5 lautet:



 
= VLOOKUP (inc,rates,3,1)+(inc- VLOOKUP (inc,rates,1,1))* VLOOKUP (inc,rates,2,1)

wobei 'Inc' (G4) und 'Raten' (B5:D11) sind benannte Bereiche , und Spalte D ist a Helferspalte das berechnet die kumulierte Gesamtsteuer in jeder Klammer.

Hintergrund und Kontext

Das US-Steuersystem ist „progressiv“, was bedeutet, dass Personen mit einem höheren zu versteuernden Einkommen einen höheren Bundessteuersatz zahlen. Die Sätze werden in Klammern bewertet, die durch einen oberen und einen unteren Schwellenwert definiert sind. Der Betrag des Einkommens, der in eine bestimmte Kategorie fällt, wird mit dem entsprechenden Satz für diese Kategorie besteuert. Wenn das zu versteuernde Einkommen steigt, wird das Einkommen in mehr Steuerklassen besteuert. Viele Steuerzahler zahlen daher mehrere unterschiedliche Sätze.





Im gezeigten Beispiel gelten die Steuerklassen und -sätze für Single Filer in den USA für das Steuerjahr 2019. Die folgende Tabelle zeigt die manuellen Berechnungen für ein zu versteuerndes Einkommen von 50.000 USD:

Halterung Berechnung Steuer
10% ($ 9.700 - $ 0) x 10% 970,00 $
12% (39.475 $ - 9.700 $) x 12% 3.573,00 $
22% (50.000 $ - 39.475 $) x 22% 2.315,50 $
24% N / A 0,00 $
32% N / A 0,00 $
35% N / A 0,00 $
37% N / A 0,00 $

Die Gesamtsteuer beträgt somit 6.858,50 USD. (im gezeigten Beispiel als 6.859 angezeigt).



Hinweise zur Einrichtung

1. Diese Formel hängt ab von SVERWEIS-Funktion im 'Annäherungs-Match-Modus'. Im ungefähren Übereinstimmungsmodus durchsucht SVERWEIS die Nachschlagewerte in einer Tabelle (die in aufsteigender Reihenfolge sortiert werden muss), bis ein höherer Wert gefunden wird. Dann wird es 'zurücktreten' und einen Wert aus der vorherigen Zeile zurückgeben. Im Falle einer genauen Übereinstimmung gibt SVERWEIS Ergebnisse aus der übereinstimmenden Zeile zurück.

2. Damit SVERWEIS die tatsächlichen kumulierten Steuerbeträge abrufen kann, wurden diese als a . in die Tabelle aufgenommen Helferspalte in Spalte D. Die nach unten kopierte Formel in D6 lautet:

 
=((B6-B5)*C5)+D5

In jeder Zeile wendet diese Formel den Satz aus der obigen Zeile auf das Einkommen in dieser Klammer an.

Excel machen eine Dropdown-Liste

3. Zur besseren Lesbarkeit folgendes benannte Bereiche , sind definiert: 'Inc' (G4) und 'Raten' (B5:D11).

Erläuterung

In G5 ist das erste SVERWEIS so konfiguriert, dass die kumulierte Steuer zum Grenzsatz mit diesen Eingaben abgerufen wird:

  • Nachschlagewert ist 'inc' (G4)
  • Nachschlagetabelle ist 'Raten' (B5:D11)
  • Spaltennummer ist 3, Kumulative Steuer
  • Übereinstimmungstyp ist 1 = ungefähre Übereinstimmung
 
 VLOOKUP (inc,rates,3,1) // returns 4,543

Bei einem zu versteuernden Einkommen von 50.000 US-Dollar entspricht SVERWEIS im ungefähren Match-Modus 39.475 und gibt 4.543 zurück, die Gesamtsteuer beträgt bis zu 39.475 US-Dollar.

Der zweite SVERWEIS berechnet das verbleibende zu versteuernde Einkommen:

 
(inc- VLOOKUP (inc,rates,1,1)) // returns 10,525

so berechnet:

(50.000-39.475) = 10.525

Schließlich erhält der dritte SVERWEIS den (höchsten) Grenzsteuersatz:

 
 VLOOKUP (inc,rates,2,1) // returns 22%

Dies wird mit dem im vorherigen Schritt berechneten Einkommen multipliziert. Die komplette Formel wird wie folgt gelöst:

 
= VLOOKUP (inc,rates,3,1)+(inc- VLOOKUP (inc,rates,1,1))* VLOOKUP (inc,rates,2,1) =4,543+(10525)*22% =6,859 

Grenz- und Effektivzinsen

Zelle G6 enthält den mit SVERWEIS berechneten oberen Grenzsatz:

 
= VLOOKUP (inc,rates,2,1) // returns 22%

Der effektive Steuersatz in G7 ist die Gesamtsteuer geteilt durch das zu versteuernde Einkommen:

 
=G5/inc // returns 13.7%

Hinweis: Ich bin auf gestoßen diese Formel auf Jeff Lennings Blog an der Excel University. Es ist ein großartiges Beispiel dafür, wie SVERWEIS im ungefähren Übereinstimmungsmodus verwendet werden kann und wie SVERWEIS mehrmals in derselben Formel verwendet werden kann.

Autor Dave Bruns


^